Nixfiles/flake.nix

{
  description = "NixOS configuration";

  inputs =
    {
      nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
      nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-21.11";
      home-manager = {
        url = "github:nix-community/home-manager";
        inputs.nixpkgs.follows = "nixpkgs";
      };
      nixpkgs-mozilla = {
        url = "github:mozilla/nixpkgs-mozilla";
        flake = false;
      };
      nvim-traxys = {
        url = "github:traxys/nvim-flake";
        inputs.nixpkgs.follows = "nixpkgs";
      };
      zsh-traxys = {
        url = "github:traxys/zsh-flake";
      };
    };

  outputs = { home-manager, nixpkgs, ... }@inputs: {
    nixosConfigurations = {
      ZeNixLaptop = nixpkgs.lib.nixosSystem rec {
        system = "x86_64-linux";
        modules = [
          ({ pkgs, ... }: {
            nixpkgs.overlays = [
              inputs.nvim-traxys.overlay."${system}"
              (import inputs.nixpkgs-mozilla)
              (final: prev: {
                firefox = inputs.nixpkgs-stable.legacyPackages."${system}".firefox;
                firefox-wayland = inputs.nixpkgs-stable.legacyPackages."${system}".firefox-wayland;
                lutris = inputs.nixpkgs-stable.legacyPackages."${system}".lutris;
              })
            ];
          })
          ./nixos/configuration.nix
          home-manager.nixosModules.home-manager
          {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.users.traxys = { config, lib, pkgs, ... }: {
              imports = [
                ./home.nix
                ./graphical.nix
                ./extra_info.nix
                ./localinfo.nix
                ./wm
                ./rustdev.nix
                ./git
                inputs.zsh-traxys.home-managerModule."${system}"
                inputs.nvim-traxys.home-managerModule."${system}"
              ];
            };
            # Optionally, use home-manager.extraSpecialArgs to pass
            # arguments to home.nix
          }
        ];
      };
    };
  };
}